AC_INIT([kingate], [0.0.1], [kingate-bugs@klever.net])
AC_CONFIG_SRCDIR([include/kingate/cgi_gateway.h])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([dist-bzip2])

AC_PROG_INSTALL
AC_PROG_AWK
AC_PROG_CXX
AC_PROG_CC
AC_PROG_LIBTOOL

AC_HEADER_STDC
AC_CHECK_HEADERS([sys/types.h sys/stat.h])
AC_CHECK_DECLS([environ],,,[
 #include <unistd.h>
])

HAVE_FCGI=false
AC_LANG_PUSH(C++)
AC_CHECK_HEADERS([fcgio.h],[
 AC_CHECK_LIB(fcgi,FCGX_Init,[
  LIBS="-lfcgi ${LIBS}"
  AC_CHECK_LIB([fcgi++],[main],[
   LIBS="-lfcgi++ ${LIBS}"
   HAVE_FCGI=true
  ])
 ])
])
AC_LANG_POP(C++)
if ! ${HAVE_FCGI} ; then
 AC_MSG_NOTICE([no FastCGI development kit found. It is highly recommnded that you get one. Meanwhile we will proceed without FastCGI support])
fi
AM_CONDITIONAL([HAVE_FCGI],[${HAVE_FCGI}])

AC_C_CONST

AC_FUNC_MALLOC
AC_FUNC_REALLOC

AC_PATH_PROG([XSLTPROC],[xsltproc],[true])

AC_WITH_PKGCONFIG

PKG_CHECK_MODULES([KONFORKA],[konforka],,[
 AC_MSG_ERROR([no konforka library found. get one from http://kin.klever.net/konforka/])
])

WANT_DOXYGEN="yes"
AC_ARG_ENABLE([doxygen],
 AC_HELP_STRING([--disable-doxygen],[do not generate documentation]),
 [
  test "${enableval}" = "no" && WANT_DOXYGEN="no"
 ]
)
if test "${WANT_DOXYGEN}" = "yes" ; then
 AC_WITH_DOXYGEN
 AC_WITH_DOT
else
 AM_CONDITIONAL([HAVE_DOXYGEN],[false])
 AM_CONDITIONAL([HAVE_DOT],[false])
fi

HAVE_MIMETIC=false
AC_LANG_PUSH(C++)
  AC_CHECK_LIB([mimetic],[main],[
   MIMETIC_LIBS=-lmimetic
   HAVE_MIMETIC=true
  ]
 )
AC_LANG_POP(C++)
AC_SUBST([MIMETIC_LIBS])
AC_SUBST([MIMETIC_CFLAGS])
if ${HAVE_MIMETIC} ; then
 AC_DEFINE([HAVE_MIMETIC],,[defined in presence of mimetic])
fi

AC_CONFIG_FILES([
 Makefile
  kingate.pc kingate-fcgi.pc kingate-plaincgi.pc
  Doxyfile
 include/Makefile
 src/Makefile
])
AC_OUTPUT