# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils postgresql

DESCRIPTION="pgLOGd writes web server log entries to a PostgreSQL database"
HOMEPAGE="http://www.digitalstratum.com/pglogd/"
SRC_URI="http://www.digitalstratum.com/pglogd/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

DEPEND="dev-db/postgresql-libs"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/${P}-path.patch
}

src_compile() {
	local pgconfig=$(postgresql_get_pgconfig)
	emake COPTS= \
		CFLAGS="${CFLAGS} -I$(${pgconfig} --includedir)" \
		LDFLAGS="${LDFLAGS} -L$(${pgconfig} --libdir)" \
		|| die "emake failed"
}

src_install() {
	dobin pglogctl
	dosbin pglogd
	dodoc CHANGELOG README pglogd_tables.sql weblog_daily.sql queries.txt pglogd.conf

	insinto /etc
	doins pglogd.conf

	exeinto /etc/init.d
	newexe ${FILESDIR}/pglogd.init pglogd
}

pkg_postinst() {
	echo
	einfo "Create a database on PostgreSQL server,"
	einfo "default name pglogd, but call it what you want,"
	einfo "and create the required tables within the database. An SQL script is"
	einfo "included with the source /usr/share/doc/${PF}/pglogd_tables.sql.gz"
	einfo "to accomplish this:"
	einfo
	einfo "  # su - postgres"
	einfo "  $ createdb pglogd"
	einfo "  $ zcat /usr/share/doc/${PF}/pglogd_tables.sql.gz | psql pglogd"
	einfo "  $ exit"
	einfo
	einfo "Then, you need to edit /etc/pglogd.conf against your enviroment."
	einfo "Finally, start up pglogd."
	einfo "   # /etc/init.d/pglogd start before apache server."
	echo
}