1 files changed, 0 insertions, 98 deletions
diff --git a/net-im/jabberd/jabberd-2.1.4.ebuild b/net-im/jabberd/jabberd-2.1.4.ebuild
deleted file mode 100644
index 4ecfc5b..0000000
--- a/net-im/jabberd/jabberd-2.1.4.ebuild
+++ b/dev/null
@@ -1,98 +0,0 @@
-# Copyright 1999-2007 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-WANT_AUTOCONF="latest"
-WANT_AUTOMAKE="none"
-inherit autotools eutils versionator
-
-DESCRIPTION="Open Source Jabber Server"
-HOMEPAGE="http://jabberd2.xiaoka.com/"
-SRC_URI="http://ftp.xiaoka.com/${PN}2/releases/${P}.tar.bz2"
-
-SLOT="0"
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
-IUSE="debug memdebug ipv6 ldap mysql pam pipe postgres sqlite ssl idn berkdb anon fs"
-
-RDEPEND=">=net-im/jabber-base-0.01
-	ssl? ( >=dev-libs/openssl-0.9.6b )
-	idn? ( net-dns/libidn )
-	ldap? ( net-nds/openldap )
-	berkdb? ( >=sys-libs/db-4.1.25 )
-	mysql? ( virtual/mysql )
-	postgres? ( dev-db/postgresql )
-	sqlite? ( =dev-db/sqlite-3* )
-	dev-libs/expat
-	dev-libs/cyrus-sasl"
-DEPEND="${RDEPEND}"
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}/${P}-configure.in.patch"
-	eautoreconf
-}
-
-src_compile() {
-
-	local localconf=
-	if use debug; then
-		localconf="${localconf} --enable-debug"
-		use memdebug && localconf="${localconf} --enable-nad-debug --enable-pool-debug"
-	else
-		if use memdebug; then
-			ewarn
-			ewarn '"memdebug" requires "debug" enabled.'
-			ewarn
-		fi
-	fi
-
-	econf \
-		--localstatedir=/var \
-		--sysconfdir=/etc/jabber \
-		--enable-db \
-		${localconf} \
-		$(use_enable anon) \
-		$(use_enable fs) \
-		$(use_enable berkdb db) \
-		$(use_enable idn) \
-		$(use_enable ipv6) \
-		$(use_enable ldap) \
-		$(use_enable mysql) \
-		$(use_enable pam) \
-		$(use_enable pipe) \
-		$(use_enable postgres pgsql) \
-		$(use_enable sqlite) \
-		$(use_enable ssl) \
-		|| die "econf failed"
-	emake || die "make failed"
-
-}
-
-src_install() {
-
-	make DESTDIR="${D}" install || die "make install failed"
-
-	fowners jabber:jabber /usr/bin/{jabberd,router,resolver,sm,c2s,s2s}
-	fperms 750 /usr/bin/{jabberd,router,resolver,sm,c2s,s2s}
-
-	newinitd "${FILESDIR}/jabberd-${PV}.init" jabberd || die "newinitd failed"
-
-	dodoc AUTHORS PROTOCOL README
-	docinto tools
-	for i in db-* migrate.pl pipe-auth.pl; do
-		dodoc tools/${i}
-	done
-
-	cd "${D}/etc/jabber/"
-	sed -i \
-		-e 's,/var/jabberd/pid/,/var/run/jabber/,g' \
-		-e 's,/var/jabberd/log/,/var/log/jabber/,g' \
-		-e 's,/var/jabberd/db,/var/spool/jabber/,g' \
-		*.xml *.xml.dist || die "sed failed"
-	use berkdb && sed -i \
-		-e 's,<module>mysql</module>,<module>db</module>,' \
-		c2s.xml*
-
-}