# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit pam eutils

DESCRIPTION="Open Source Jabber Server"
HOMEPAGE="http://jabberd2.xiaoka.com/"
SRC_URI="http://ftp.xiaoka.com/${PN}2/releases/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="debug memdebug ldap mysql pam pipe postgres sqlite ssl berkdb anon fs"

RDEPEND=">=net-im/jabber-base-0.01
	ssl? ( >=dev-libs/openssl-0.9.6b )
	idn? ( net-dns/libidn )
	ldap? ( net-nds/openldap )
	berkdb? ( >=sys-libs/db-4.1.25 )
	mysql? ( virtual/mysql )
	postgres? ( virtual/postgresql-libs )
	sqlite? ( =dev-db/sqlite-3* )
	dev-libs/expat
	dev-libs/cyrus-sasl"
DEPEND="${RDEPEND}"

src_compile() {

	if use memdebug && ! use debug ; then
		ewarn '"memdebug" requires "debug"'
	fi

	# gsasl backend is disabled due to the lack of proper gsasl in the tree
	# TODO: rework postgres part in configure.ac
	# TODO: conditionally add extra include path for db_includedir from
	# db-use.eclass
	econf \
		--localstatedir=/var \
		--sysconfdir=/etc/jabber \
		$(use_enable debug) \
		$(use_enable memdebug nad-debug) $(use_enable memdebug pool-debug) \
		--enable-sasl=cyrus \
		$(use_enable ssl) \
		$(use_enable mysql) \
		$(use_enable postgres pgsql) \
		$(use_enable sqlite) \
		$(use_enable berkdb db) \
		$(use_enable ldap) \
		$(use_enable pam) \
		$(use_enable pipe) \
		$(use_enable anon) \
		$(use_enable fs) \
		|| die "econf failed"
	emake || die "make failed"

}

src_install() {

	make DESTDIR="${D}" install || die "make install failed"

	fowners jabber:jabber /usr/bin/{jabberd,router,resolver,sm,c2s,s2s}
	fperms 750 /usr/bin/{jabberd,router,resolver,sm,c2s,s2s}

	newinitd "${FILESDIR}/jabberd-${PV}.init" jabberd || die "newinitd failed"
	use pam && newpamd "${FILESDIR}/jabberd-${PV}.pamd" jabberd || die "newpamd failed"

	dodoc AUTHORS BUGS NEWS PROTOCOL README UPGRADE
	docinto tools
	for i in db-* migrate.pl pipe-auth.pl; do
		dodoc tools/${i}
	done

	cd "${D}/etc/jabber/"
	sed -i \
		-e 's,/var/jabberd/pid/,/var/run/jabber/,g' \
		-e 's,/var/jabberd/log/,/var/log/jabber/,g' \
		-e 's,/var/jabberd/db,/var/spool/jabber/,g' \
		*.xml *.xml.dist || die "sed failed"
	use berkdb && sed -i \
		-e 's,<module>mysql</module>,<module>db</module>,' \
		c2s.xml*

}

pkg_postinst() {
	if use pam ; then
		echo
		ewarn 'Jabberd-2 PAM authentication requires your unix usernames to'
		ewarn 'be in the form of "contactname@jabberdomain".  This behavior'
		ewarn 'is likely to change in future versions of jabberd-2. It may'
		ewarn 'be advisable to avoid PAM authentication for the time being.'
		echo
		ebeep
	fi
}