kdepimpi-x11: initial commitHEADmaster

1 files changed, 50 insertions, 0 deletions

diff --git a/packages/kdepimpi/kdepimpi-x11_git.bb b/packages/kdepimpi/kdepimpi-x11_git.bb
new file mode 100644
index 0000000..dd8f74e
--- a/dev/null
+++ b/packages/kdepimpi/kdepimpi-x11_git.bb
@@ -0,0 +1,50 @@
+DESCRIPTION = "qt4-x11 port of kdepmipi"
+SECTION = "x11/applications"
+PRIORITY = "optional"
+LICENSE = "GPL"
+
+SRCTAG="p2"
+PV = "2.2.8+git+${SRCTAG}"
+PR = "r2"
+
+SRC_URI = "git://git.klever.net/patchwork/kdepimpi.git;protocol=git;tag=${SRCTAG}"
+S = "${WORKDIR}/git"
+
+inherit qmake-base qt4x11
+
+do_configure() {
+        ${OE_QMAKE_QMAKE} -recursive kdepim-desktop.pro QMAKE_UIC3="${OE_QMAKE_UIC3}"
+}
+PARALLEL_MAKE=''
+do_compile() {
+        oe_runmake
+}
+do_install() {
+        install -d ${D}${bindir}
+        install -m 0755 ${S}/bin/{kapi,kopi,pwmpi} ${D}${bindir}/
+        install -d ${D}${libdir}/
+        cp -Rpd ${S}/bin/libxmicro{gammu,kabc,kcal,kde,kdepim,libetpan}.so.* ${D}${libdir}/
+        install -d ${D}${libdir}/kdepimpi
+        cp -Rpd ${S}/bin/kdepim/{kaddressbook,korganizer,pwmanager} ${D}${libdir}/kdepimpi/
+        install -m 755 ${S}/bin/libxmicrokabc_{dir,file,qtopia}.so ${D}${libdir}/kdepimpi/kaddressbook/
+        install -d ${D}/${datadir}/applications
+        for de in ${S}/{korganizer/korganizer,kaddressbook/kaddressbook,pwmanager/pwmanager/pwmanager}.desktop ; do
+                bn="$(basename "$de")"
+                sed <$de \
+                        -e '/^CanFastLoad/d' -e 's,^Icon *= *kdepim/\(.*\),Icon = ${libdir}/kdepimpi/\1,g' \
+                        >${D}${datadir}/applications/${bn}
+        done
+}
+
+PACKAGES = "${PN}-kapi ${PN}-kopi ${PN}-pwmpi \
+        ${PN}-libxmicrokabc \
+        ${PN}-libxmicrokcal ${PN}-libxmicrokde ${PN}-libxmicrokdepim ${PN}-libxmicrolibetpan"
+
+FILES_${PN}-kapi = "${bindir}/kapi ${libdir}/kdepimpi/kaddressbook ${datadir}/applications/kaddressbook.desktop"
+FILES_${PN}-kopi = "${bindir}/kopi ${libdir}/kdepimpi/korganizer ${datadir}/applications/korganizer.desktop"
+FILES_${PN}-pwmpi = "${bindir}/pwmpi ${libdir}/kdepimpi/pwmanager ${datadir}/applications/pwmanager.desktop"
+FILES_${PN}-libxmicrokabc = "${libdir}/libxmicrokabc.so.*"
+FILES_${PN}-libxmicrokcal = "${libdir}/libxmicrokcal.so.*"
+FILES_${PN}-libxmicrokde = "${libdir}/libxmicrokde.so.*"
+FILES_${PN}-libxmicrokdepim = "${libdir}/libxmicrokdepim.so.*"
+FILES_${PN}-libxmicrolibetpan = "${libdir}/libxmicrolibetpan.so.*"